  10 :RETURN ;CLEAR ;NT=30;BC=4;FC=4;H=0
  15 PRINT "12-31 12-3150";NT=1;CLEAR ;BC=33
  20 Q=0;C=0;M=RND (5);T=RND (9);FOR Z=1TO 45;@(Z)=RND (6);NEXT Z;R=@((M-1)×9+T)
  25 H=H+1;IF H=4GOTO 6000
  30 PRINT ;PRINT "INSPECTOR CLEW-SO, WHO IS YOUR SUSPECT?";S=KP-48
  60 CLEAR ;PRINT ;PRINT "DO YOU WISH TO QUESTION";GOSUB 8000+S;PRINT " ABOUT:
  80 PRINT "1-",;GOSUB 8000+S;PRINT "'S WHEREABOUTS
 100 PRINT "2-WHEN ",;GOSUB 8000+S;PRINT " WAS WHERE
 120 PRINT "3-THE CRIME IS SOLVED!";A=KP-48
 140 Q=Q+1;CLEAR ;GOTO A×200
 200 PRINT ;GOSUB 8000+S;PRINT ", WHERE WERE YOU AT ",;A=KP-48;TV=A+48;PRINT 
 220 P=@((S-1)×9+A);IF S=MIF RND (2)=1P=RND (6);IF RND (2)=1Z=RND (2);GOSUB 7000;GOTO 330
 270 IF (P#R)+(RND (2)=1)GOTO 330
 290 IF A<T Z=1;GOSUB 7000
 295 IF A>T Z=2;GOSUB 7000
 330 PRINT ;PRINT "I WAS IN THE ",;GOSUB 9000+P;PRINT 
 340 FOR K=1TO 5;IF K=SGOTO 370
 350 U=@((K-1)×9+A);IF U=PPRINT "I WAS WITH ",;GOSUB 8000+K;PRINT 
 360 IF ABS(P-U)=1PRINT "I SAW ",;GOSUB 8000+K;PRINT 
 370 NEXT K;GOTO 30
 400 PRINT ;GOSUB 8000+S;PRINT ", WHEN WERE YOU IN THE";B=KP-48;GOSUB 9000+B;PRINT 
 430 IF S=MIF RND (2)=1V=RND (9);GOSUB 500;PRINT ;GOTO 30
 440 W=0;V=1;FOR K=(S-1)×9+1TO S×9;IF @(K)=BIF W=0W=1;GOSUB 500;GOTO 460
 450 IF @(K)=BPRINT ",",;GOSUB 510
 460 V=V+1;NEXT K;IF W=1PRINT ;GOTO 30
 470 PRINT "I WAS NOT IN THE ",;GOSUB 9000+B;PRINT ;GOTO 30
 500 PRINT "I WAS IN THE ",;GOSUB 9000+B;PRINT ;PRINT "AT",
 510 PRINT #2,V,;RETURN 
 600 C=C+1;PRINT ;PRINT "INSPECTOR, DO YOU THINK
 610 PRINT "YOU KNOW:";PRINT "1-KILLER";PRINT "2-ROOM";PRINT "3-TIME";PRINT "4-TOTALLY BAFFLED";G=KP-48
 620 GOTO 600+G×100
 700 PRINT "THE KILLER? ",;G=KP-48;GOSUB 8000+G;PRINT "?";IF G#MGOTO 5000
 710 GOTO 920
 800 PRINT "ROOM OF MURDER?";G=KP-48;GOSUB 9000+G;PRINT "?";IF G#RGOTO 5000
 820 GOTO 920
 900 PRINT "TIME OF MURDER? ",;G=KP-48;TV=G+48;PRINT "?";IF G#TGOTO 5000
 920 PRINT "YOU ARE CORRECT!";GOTO 25
1000 GOSUB 8000+M;PRINT " KILLED THE HOST AT ",#1,T," O'CLOCK IN THE ",;GOSUB 9000+R;GOTO 6020
5000 PRINT "YOU ARE A BUMBLING IDIOT!";GOTO 30
6000 PRINT "YOU ARE BRILLIANT!";PRINT "IT TOOK YOU ",#1,Q," QUESTIONS,
6010 PRINT "AND ",#1,C," CONFRONTATIONS!
6020 IF KPGOTO 10
7000 PRINT "THE HOST WAS ",;IF Z=2GOTO 7020
7010 PRINT "STILL ALIVE!";RETURN 
7020 PRINT "ALREADY DEAD!";RETURN 
8001 PRINT "BILL",;RETURN 
8002 PRINT "MARY",;RETURN 
8003 PRINT "PAUL",;RETURN 
8004 PRINT "SUZY",;RETURN 
8005 PRINT "JOHN",;RETURN 
9001 PRINT "LOUNGE",;RETURN 
9002 PRINT "ATRIUM",;RETURN 
9003 PRINT "LIVING ROOM",;RETURN 
9004 PRINT "DINING ROOM",;RETURN 
9005 PRINT "TROPHY ROOM",;RETURN 
9006 PRINT "GARAGE",;RETURN 
RUN 
